通配符查找 指定目录下文件的过程：

--查找指定文件夹(目录)下的文件。
ALTER PROCEDURE [FileS].[DIR_FileS]
@Path nvarchar(1000) --搜索路径。
        --表示【文件夹路径】必须以'\'结尾；
        --表示【文件路径】不能以\结尾。（文件名可带通配符）
,@FileS nvarchar(MAX) OUTPUT --返回 找到的 文件名串
,@Depth int=1 --搜索[文件夹]深度。不为1，将搜索[子文件夹]。0全部目录，1 第一级目录，2 第二级目录 依此类推
,@FG nvarchar(10)=NULL --文件名串的 分隔符；默认char(13)
AS
BEGIN
        SET NOCOUNT ON;        
        SET @FG=ISNULL(@FG,char(13));--分隔符；默认char(13)
        IF @Depth<0 SET @Depth=1;--深度为负数，改1

        SET @FileS=NULL;
        DECLARE @Tab table ([FileName] nvarchar(Max),depth smallint,isfile bit); 
        DECLARE @FileName as nvarchar(Max);
        DECLARE @i as int;
        
        --整理 参数 @Path 
        SET @Path =RTRIM(LTRIM(ISNULL(@Path,''))); --'
        IF LEN(@Path)<2 GOTO END1; --无效的参数 @Path 
        
        --分离 文件名（带通配符）
        IF CHARINDEX('\',@Path,1)>0 AND RIGHT(@Path,1)<>'\' BEGIN     --'           
                --取最右侧'\' 位置
                SET @i =LEN(@Path);
                while @i>0 AND SUBSTRING(@Path,@i,1)<>'\' BEGIN   --'
                        SET @i=@i-1;
                        END;
                IF @i>0 BEGIN 
                        --截取 文件名
                        SET @FileName=SUBSTRING(@Path,@i+1,LEN(@Path));
                        SET @Path =SUBSTRING(@Path,1,@i-1);
                        --转换通配符
                        SET @FileName=replace(@FileName,'*','%');
                        SET @FileName=replace(@FileName,'?','_');
                        END;
                END;
        --print '@Path='+ISNULL(@Path,'')+'  @FileName='+ISNULL(@FileName,'');
         
        insert @Tab exec master..xp_dirtree @Path
        ,@Depth --查找深度：0全部目录，1 第一级目录，2 第二级目录 依此类推
        ,1 ;--0文件夹，非0：文件夹和文件名

        --删除不匹配 记录
        IF ISNULL(@FileName,'')<>'' BEGIN 
                --select [FileName] from @Tab WHERE [isfile]=1 AND [FileName]like @FileName ;        
                DELETE @Tab WHERE [isfile]<>1 OR [FileName]not like @FileName;                        
                END;
        ELSE DELETE @Tab WHERE [isfile]<>1;
        
        --拼装 文件名串；加 分隔符@FG
        SET @FileS='';
        SELECT @FileS=@FileS+@FG+ISNULL([FileName],'') FROM @Tab;        
        IF @FileS<>''BEGIN  --去除首位 分隔符@FG
                IF SUBSTRING(@FileS,1,LEN(@FG))=@FG BEGIN ;
                        SET @FileS=SUBSTRING(@FileS,LEN(@FG)+1,LEN(@FileS));
                        END;
                END;        
END1:
        --print '@FileS='+@FileS;
        --select [FileName] from @Tab;
END